利用XML開發留言板簡單的例子

2024-09-05 20:54:04

字體：大中小

來源：轉載

供稿：網友

XML是一種基于文本格式的元標記語言，它注重對數據結構和數據意義的描述，實現了數據內容和顯示樣式的分離（xml xsl），而且是與平臺無關的。

由于XML注重數據內容的描述，因而，對于數據的檢索非常有意義，我們不會再象HTML那樣，檢索出與我們要求無關的信息。

另一方面，XML文件是數據的載體，利用XML作為數據庫，不需要訪問任何數據庫系統，我們可以使用任意WEB技術來顯示我們的數據，比如HTML，FlashMX 等。

由于世界各大計算機公司的積極參與，XML正日益成為基于互聯網的數據格式新一代的標準。

下面利用XML作為數據的載體，開發一個基于XML的留言板。

首先，我們建立XML文件guestbook.xml，該文件記錄了留言者的姓名、電子郵件、網址、留言內容。當然，我們也可以根據需要添加任意多的信息。文件內容如下：
　
<?xml version="1.0" encoding="gb2312"?>
<留言本>
<留言記錄>
<留言者姓名>KAI</留言者姓名>
<電子郵件>kai@hostx.org</電子郵件>
<網址>http://www.17xml.com </網址>
<留言內容>千山萬水總是情，常來泡妞行不行？咔咔:_)</留言內容>
</留言記錄>
</留言本>
　
由于目前許多服務器都支持ASP，我們采用常見的ASP來作為實現的工具，guestbook.asp文件如下：
　
<%@Language="VBScript"%>
<%
'設置Web頁面的信息
Response.Buffer = true
Response.Expires = -1
　
'顯示留言函數init()
'www.56wlw.com
Function init()
entryForm()
　
'定義局部變量
Dim objXML
Dim arrNames
Dim arrEmails
Dim arrURLS
Dim arrMessages
　
'創建XMLDOM文檔對象，用來存放留言
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
　
'取得留言本各元素的集合
Set arrNames = objXML.getElementsByTagName("留言者姓名")
Set arrEmails = objXML.getElementsByTagName("電子郵件")
Set arrURLS = objXML.getElementsByTagName("網址")
Set arrMessages = objXML.getElementsByTagName("留言內容")
　
Response.Write "<table border='0' width='100%'>"
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>"
Response.Write "<b>各位的留言如下：</b>"
Response.Write "</td></tr>"
　
'輸出留言本各元素的內容，最新的留言先顯示
For x=arrNames.length-1 To 0 Step -1
Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>"
Response.Write "<tr><td>網址：<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>"
Response.Write "<tr><td>留言內容：</td></tr>"
Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>"
Response.Write "<tr><td> </td></tr>"
Next
　
Response.Write "</table>"
Set objXML = nothing
End Function
　
'向XML文件添加留言記錄的函數addEntry()
Function addEntry()
　
'定義局部變量
Dim strName
Dim strEmail
Dim strURL
Dim strMessage
　
'取得留言表單的輸入內容
strName = Request.Form("姓名")
strEmail = Request.Form("電子郵件")
strURL = Request.Form("網址")
strMessage = Request.Form("留言")
　
Dim objXML
Dim objEntry
Dim objName
Dim objEmail
Dim objURL
Dim objMessage
　
'向XML文件添加留言內容
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))
　
Set objEntry = objXML.createNode("element", "留言記錄", "")
objXML.documentElement.appendChild(objEntry)
　
Set objName = objXML.createNode("element", "留言者姓名", "")
objEntry.appendChild(objName)
objName.text = strName
　
Set objEmail = objXML.createNode("element", "電子郵件", "")
objEntry.appendChild(objEmail)
objEmail.text = strEmail
　
Set objURL = objXML.createNode("element", "網址", "")
objEntry.appendChild(objURL)
objURL.text = strURL
　
Set objMessage = objXML.createNode("element", "留言內容", "")
objEntry.appendChild(objMessage)
objMessage.text = strMessage
　
objXML.save(server.MapPath("guestbook.xml"))
　
Response.Redirect("guestbook.asp")
　
End function
　
'填寫和發送留言表單的函數entryForm()
Function entryForm()
　
Response.Write "<p align='center'><b>XML 留言本例子</b></p>"
Response.Write "<hr color='#000099' width='100%' noshade>"
Response.Write "<form action=guestbook.asp?action=addEntry method=post>"
Response.Write "<table border=1>"
Response.Write "<tr><td>您的姓名：</td><td><input type=text name=姓名 /></td></tr>"
Response.Write "<tr><td>電子郵件：</td><td><input type=text name=電子郵件 /></td></tr>"
Response.Write "<tr><td>您的網址：</td><td><input type=text name=網址 /></td></tr>"
Response.Write "<tr><td>您的留言：</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>"
Response.Write "<tr><td> </td><td><input type=submit value=發布留言 /></td></tr>"
Response.Write "</table>"
Response.Write "</form>"
　
End Function
%>
<html>
<head>
<title>XML 留言例子</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body>
<%
'判斷是否發送了留言，并更新留言信息
Dim a
a = Request.Querystring("action")
If a<>"" Then
addEntry
else
init
End If
%>
</body>
</html>
　
以上是利用XML開發留言板簡單的例子，完全是拋磚引玉，可以根據需要進行添加更多的功能，所有程序在WIN2000 IIS5.0 IE5.5調試通過.