你先打開你的U盤，然后點擊工具欄——文件夾選項，在打開的對話框中選查看，在高級設置里找到隱藏文件和文件夾選項，點擊顯示所有文件和文件夾選項，最后點確定就可以了

關于U盤中毒，隱藏屬性無法取消的解決辦法:

attrib命令：網上那些用法，看得我內分泌失調，到現在都不知道attrib的正確用法。
網上找到一個批處理，很方便，可以批量設置或取消隱藏屬性和系統屬性。
1、新建一個.txt文檔
2、把下面的代碼復制進去
3、保存
4、把.txt后綴改成.bat
5、不要雙擊使用，用的時候直接把要改屬性的文件或文件夾拖到.bat文件圖標上
如果你是U盤根目錄被感染，直接把U盤盤符拖上去，一路選2，回車


---------------------以下是代碼（不含本行）----------------------
@echo off&setlocal enableextensions enabledelayedexpansion
title 修改系統文件屬性和隱藏文件屬性
if "%~1"=="" (echo 你沒有拖入 任何磁盤或文件或文件夾
echo 請把 要處理的磁盤或文件或文件夾 拖到 批處理文件圖標
echo 不要 雙擊啟動 批處理&pause&goto :eof)
call:choose "設置隱藏文件屬性,請選擇:" 不改變 去掉 設置
(set h=)&(if !c! equ 2 set h=-)&(if !c! equ 3 set h=+)
call:choose "設置系統文件屬性,請選擇:" 不改變 去掉 設置
(set s=)&(if !c! equ 2 set s=-)&(if !c! equ 3 set s=+)
call:choose "設置應用范圍,請選擇:" 文件或文件夾自身屬性及第一級目錄內容屬性 文件夾第一級目錄內容屬性
for %%i in (%*) do (if !c! equ 1 call:attrib "%%~i"
for /f "delims=" %%j in ('dir /a /b "%%~i"') do call:attrib "%%~i/%%~j")
pause&goto :eof
:choose
(set c=)&(set n=)&for %%i in (%*) do echo !n! %%~i&set /a n+=1
(set /p c=)&(set /a c=c)&if !c! geq 0 if !c! leq !n! echo.&goto :eof
goto choose
:attrib
setlocal&(set a=)&(set a=%~a1)&if "!a!"=="" goto :eof
if not defined h if "!a:~3,1!"=="h" (set h=+) else (set h=-)
if not defined s if "!a:~4,1!"=="s" (set s=+) else (set s=-)
echo 正在處理: %~1&attrib !h!h !s!s "%~1"&goto :eof